home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1992 June
/
64er_Magazin_92-06_1992_Markt__Technik_de_Side_B.d64
/
b-copper 1.asc
< prev
next >
Wrap
Text File
|
2022-10-26
|
2KB
|
75 lines
;***************************************
;** border-copperbars (w) '92 by pit **
;***************************************
*= $1000 ;startadresse $1000
sei ;irq setzen
lda #<start ;vektoren
sta $0314 ;auf eigene
lda #>start ;routine
sta $0315 ;verbiegen
lda #$01 ;nur raster-irq
sta $d01a ;zulassen
lda $d011 ;y-scroll register
and #$7f ;auf original-wert
sta $d011 ;setzen
lda #$00 ;ghost-byte
sta $3fff ;loeschen
cli ;irq-flag loeschen
rts ;zurueck
start lda $dc0d ;irq von der
bmi border ;cia oder vom vic?
lda $d019 ;irr loeschen
sta $d019 ;
jmp $ea81 ;und zum alten irq
;--- --- --- --- --- --- --- --- --- ---
border lda #$f0 ;rasterstrahl auf
rzy1 cmp $d012 ;position $f0 ??
bne rzy1 ;
ldx #$21 ;warteschleife
rzy2 dex ;zum austimen
bne rzy2 ;
ldx #$00 ;
rzy3 txa ;akku
and #$07 ;verknuepfen
ora #$18 ;(kein text)
ldy colors,x;farbe laden
sta $d011 ;verknuepfter wert
;in $d011 schreiben
sty $d020 ;und farben in
sty $d021 ;die farbregister
jsr wait ;austimen
jsr wait ;austimen
inx ;
cpx #$28 ;schon alle farben?
bne rzy3 ;
lda #$00 ;bildschirm
sta $d020 ;auf schwarz
sta $d021 ;setzen
jmp $ea31 ;alter irq
wait bit $ff ;3 zyklen +
nop ;2 zyklen warten
rts ;und zurueck
;--- --- --- --- --- --- --- --- --- ---
colors .byte $06,$00,$06,$04,$00,$06
.byte $04,$0e,$03,$00,$06,$04
.byte $0e,$03,$07,$00,$06,$04
.byte $0e,$03,$07,$01,$00,$06
.byte $04,$0e,$03,$07,$01,$07
.byte $03,$0e,$04,$06
;--- --- --- --- --- --- --- --- --- ---